VBA ファイルやフォルダと特殊なパスを取得する

はじめに

Excel VBA マクロでファイルやフォルダのパスと特殊なパスを取得する方法を紹介します。

File, Folder オブジェクトの Path プロパティから、そのパスを取得できます。

エクセルの実行パスや Windows のパスなども取得できます。

FileSystemObject について

ここでは VBA の標準の関数より便利な FileSystemObject を使った方法を紹介しています。基本的な使い方については「FileSystemObject ファイル操作の基礎」をご覧ください。

コードを見やすくするため FileSystemObject を参照設定しています。また、エラー処理は行っていません。

ファイルやフォルダのパスを取得する

ファイルのパスを取得

フォルダ内にあるファイルのパスを取得するには次のようにします。

Dim fso As FileSystemObject
Set fso = New FileSystemObject

Dim fl As Folder
Set fl = fso.GetFolder("D:\TipsFolder") ' フォルダを取得

Dim s As String
Dim f As File
For Each f In fl.Files ' フォルダ内のファイルを取得
    s = f.Path      ' パスを取得
    Debug.Print(s) ' D:\TipsFolder\Tips.txt など
Next

' 後始末
Set fso = Nothing

fso.GetFolder 関数で指定したパスの Folder オブジェクトを取得します。フォルダが存在しないときはエラーが発生します。

fl.Files プロパティから、そのフォルダの File オブジェクトの一覧を取得できます。

f.Path プロパティから、そのファイルのパスを取得します。File オブジェクトさえ取得できれば、そこからパスを取得できます。

フォルダのパスを取得

サブフォルダのパスを取得するには次のようにします。

Dim fso As FileSystemObject
Set fso = New FileSystemObject

Dim pfl As Folder
Set pfl = fso.GetFolder("D:\TipsFolder") ' 親フォルダを取得

Dim s As String
Dim fl As Folder
For Each fl In pfl.SubFolders ' サブフォルダの一覧を取得
    s = fl.Path     ' パスを取得
    Debug.Print(s) ' D:\TipsFolder\SubTips など
Next

' 後始末
Set fso = Nothing

fso.GetFolder 関数で指定したパスの Folder オブジェクトを取得します。フォルダが存在しないときはエラーが発生します。

pfl.SubFolders プロパティから、そのフォルダ内にある Folder オブジェクトの一覧を取得できます。

fl.Path プロパティから、そのフォルダのパスを取得します。Folder オブジェクトさえ取得できれば、そこからパスを取得できます。

特殊フォルダのパスを取得する

Application オブジェクトから取得

Dim s As String

s = Application.DefaultFilePath
Debug.Print(s) ' C:\Users\Tipsfound\Desktop

%USERNAME% はログインしているユーザー名に置き換わります。

FileSystemObject オブジェクトから取得

Dim fso As FileSystemObject
Set fso = New FileSystemObject ' インスタンス化

Dim s As String
Dim fl As Folder
Set fl = fso.GetSpecialFolder(WindowsFolder)
s = fl.Path
Debug.Print(s) ' C:\Windows

Set fso = Nothing

WScript.Shell オブジェクトから取得

Dim wsh As Object
Set wsh = CreateObject("WScript.Shell") ' インスタンス化

Dim s As String
s = wsh.SpecialFolders("Desktop")       
Debug.Print(s) ' C:\Users\Tipsfound\Desktop

Set wsh = Nothing

環境変数のパスを取得

Dim wsh As Object
Set wsh = CreateObject("WScript.Shell") ' インスタンス化

Dim s As String
s = wsh.ExpandEnvironmentStrings("%ProgramFiles%")
Debug.Print(s) ' C:\Program Files (x86)

Set wsh = Nothing