更新日：2022/09/23、作成日：2014/01/27

エクセル COUNTIFS 関数：複数の条件に一致するセルを数える

はじめに

エクセルの COUNTIFS 関数の使い方を紹介します。

COUNTIFS 関数は複数の条件に一致するセルの数を数えます。「COUNTIF 関数」を複数条件に対応した上位互換の関数です。

=COUNTIFS(A1:A3,">=100",A1:A3,"<=999") のようにして、100 ～ 999 の範囲のセルの数をカウントできます。

ワイルドカードを使用して部分一致にしたり、以上や以下などを複数条件にしてセルを数えたいときに使用します。

文字列かどうかや空白など、特定の値を条件にする方法は「COUNTIF 関数」にまとめています。

COUNTIFS 関数の引数

COUNTIFS(範囲1, 条件1)
COUNTIFS(範囲1, 条件1, 範囲2, 条件2 …)
すべての範囲の中ですべての条件を満たすセルの数を数えます。

引数「範囲」	引数「条件」の対象になるセルの範囲を指定します。	配列不可
引数「条件」	数える条件を比較演算子やワイルドカードを使って指定します。	スピル化

スピル化：セルの範囲や配列を指定すると結果が「スピル」します。

配列不可：配列を指定できません。セルの範囲のみ指定できます。

引数「条件」

使用できる比較演算子には次のものがあります。

演算子	演算名	使用例	結果
=	等しい	"=2"	2 と同じ
<>	等しくない	"<>2"	2 以外
>	大きい	">2"	2 より大きい
<	小さい	"<2"	2 より小さい
>=	以上	">=2"	2 以上
<=	以下	"<=2"	2 以下

使用できるワイルドカードには次のものがあります。

パターン	説明	使用例	一致例
*	任意の長さの文字	"あ*"	あ, あい, あいう
?	任意の 1 文字	"あ?"	あい, あか, あき
~	ワイルドカードの文字 * ? を検索する	"あ~?~*"	あ?*

スポンサーリンク

使い方、条件が一つ

COUNTIFS 関数の条件が一つの使い方を紹介します。

値が 100 以上のセルの数を数える

セルの範囲「B3」～「B5」の値が 100 以上のセルを数えます。

=COUNTIFS(B3:B5,">=100")

値がエクセルのセルの数を数える

値がエクセルのセルを数えます。

=COUNTIFS(B3:B5,"=エクセル")

特定の文字が入っているセルの数を数える

ワイルドカードを使用して、値にワードが入っているセルを数えます。

=COUNTIFS(B3:B6,"=*ワード*")
=COUNTIFS(B3:B6,"=ワード*")
=COUNTIFS(B3:B6,"=*ワード")

値がワードで始まる値は "=ワード*" のように入力します。

値がワードで終わる値は "=*ワード" のように入力します。

使い方、複数条件

COUNTIFS 関数の複数条件の使い方を紹介します。

数値が指定の範囲内のセルの数を数える

値が 100 以上でセル「C3」以下のセルを数えます。

=COUNTIFS(B3:B7,">=100",B3:B7,"<="&C3)

"比較演算子"&セル名のようにしてセル参照を使用できます。

日付が指定の範囲内のセルの数を数える

日付の値がセル「C3」以上で 2000/12/31 までのセルを数えます。

=COUNTIFS(B3:B7,">="&C3,B3:B7,"<"&DATE(2001,1,1))

終了日を "<="&DATE(2000,12,31) にすると、時刻が含まれるときに終了日が条件に一致しなくなるので、次の日より小さい判定にしています。

名前がエクセルかつ値が 100 以上のセルの数を数える

名前がエクセルで値が 100 以上のセルを数えます。

=COUNTIFS(B3:B6,"=エクセル",C3:C6,">=100")

高度な使い方

COUNTIFS 関数と他の関数を組み合わせた使い方などを紹介します。

OR 条件

複数条件のどれか一つでも条件に一致しているセルの数を数えるには、判定用の列を作成してその中に「OR 関数」で条件を入力します。その結果を引数「範囲」に指定してカウントします。

名前がエクセルまたはバージョンが 365 の条件を入力します。

=OR(B3="エクセル",C3=365)

その結果が TRUE のものを引数「条件」に指定してセルの数を数えます。

=COUNTIFS(D3:D7,TRUE)

条件が 1 つになるので「COUNTIF 関数」でも同じようにできます。

判定用の列を作成しない (スピル)

判定用の列を作成しないでカウントするには「スピル」を使用します。

=SUM(IF((B3:B7="エクセル")+(C3:C7>=100),1,0))

「IF 関数」の中にセルの範囲を入力しているのでスピルします。

「IF 関数」の条件に一致するときは 1 を返しています。それを「SUM 関数」で合計してカウントします。

条件に「OR 関数」を使用していないのはスピルされないためです。

スピルで AND や OR 条件にするには「スピル、動的配列数式の使い方」をご覧ください。

スピルは 365 または 2021 から使用できます。

数式を Ctrl + Shift + Enter で確定すると「配列数式」になり、すべてのバージョンで使用できます。

判定用の列を作成しない (ラムダ)

判定用の列を作成しないでカウントするには「MAP 関数」を使用します。複雑なので詳細は関数のページをご覧ください。

=SUM(
MAP(B3:B7,C3:C7,
LAMBDA(b,c,
IF(OR(b="エクセル",c>=100),1,FALSE))))

「MAP 関数」に条件を入力します。OR 条件にしたり、「EXACT 関数」を使用して大文字小文字を区別できます。

ラムダは 365 で使用できます。

解説

引数「範囲」と 2 つ目以降の引数「範囲」の大きさが違うときはエラー #VALUE! になります。

引数「条件」に比較演算子を入力するときは "" で囲んで入力します。

引数「条件」に比較演算子を省略した "エクセル" は "=エクセル" と同じ条件になります。

引数「条件」にセル参照を入力するときは "比較演算子"&セル名のように & で比較演算子とセル名を結合します。

引数「条件」に日付を入力するときは「DATE 関数」を使用します。時刻を入力するときは「TIME 関数」を使用します。"="&DATE(2000,1,1) のように & で比較演算子と結合します。

引数「条件」は大文字と小文字を区別しません。 "=ABC" としたときは abc などと一致します。

スポンサーリンク

著者：Tipsfound